[OpenGL] 머티리얼 (Material)

■ Material

실제 세계에서 사물들은 빛에 각자 다르게 반응한다. OpenGL에서 각 유형의 오브젝트들을 시뮬레이션하기 위해 오브젝트에 3가지의 Lighting 요소(Ambient, Diffuse, Specular)와 Shininess 요소를 추가하여 Material 속성을 정의한다.

// Fragment Shader
#version 330 core
struct Material
{
    vec3 ambient; // 주변광에 대한 컬러를 정의
    vec3 diffuse; // 분산광에 대한 컬러를 정의
    vec3 specular; // 반사광에 대한 컬러를 정의
    float shininess; // Specualr 하이라이트 퍼짐의 정도
};

uniform Material material;

 

http://devernay.free.fr/cours/opengl/materials.html의 테이블의 값으로 실제 Material을 시뮬레이션 해 볼수 있다.

 

lightColor(광원) 또한 요소들을 나누어 각각 다른 세기를 설정해준다.

struct Light
{
    vec3 position;
    vec3 ambient;
    vec3 diffuse;
    vec3 specular;
};

uniform Light light;

 

 

● Material 세팅

material uniform으로 변수에 접근하여 lighting 계산을 바꿀 수 있다.

// Fragment Shader
void main()
{    
    // ambient
    vec3 ambient = light.ambient * material.ambient;

    // diffuse 
    vec3 norm = normalize(Normal);
    vec3 lightDir = normalize(lightPos - FragPos);
    float diff = max(dot(norm, lightDir), 0.0);
    vec3 diffuse = light.diffuse * (diff * material.diffuse);

    // specular
    vec3 viewDir = normalize(viewPos - FragPos);
    vec3 reflectDir = reflect(-lightDir, norm);  
    float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
    vec3 specular = light.specular * (spec * material.specular); 

    vec3 result = ambient + diffuse + specular;
    FragColor = vec4(result, 1.0);
}

 

 

struct를 채우기 위해서는 각 uniform 변수를 설정해주어야 한다.

// material
glUniform3f(glGetUniformLocation(lightingShader.ID, "material.ambient"), 1.0f, 0.5f, 0.31f);
glUniform3f(glGetUniformLocation(lightingShader.ID, "material.diffuse"), 1.0f, 0.5f, 0.31f);
glUniform3f(glGetUniformLocation(lightingShader.ID, "material.specular"), 0.5f, 0.5f, 0.5f);
glUniform1f(glGetUniformLocation(lightingShader.ID, "material.shininess"), 32.0f);

// light
glUniform3f(glGetUniformLocation(lightingShader.ID, "light.ambient"), 0.2f, 0.2f, 0.2f);
glUniform3f(glGetUniformLocation(lightingShader.ID, "light.diffuse"), 0.5f, 0.5f, 0.5f);
glUniform3f(glGetUniformLocation(lightingShader.ID, "light.specular"), 1.0f, 1.0f, 1.0f);

 

* 오브젝트의 원래 색상은 material.diffuse 값이 의미한다.

 

빛의 색상은 오브젝트의 출력 색상에 큰 영향을 미친다. 빛의 색상에 따른 오브젝트 출력 색상의 변화를 보기 위해 ambient와 diffuse 색상을 바꿔 빛의 색상을 수정할 수 있다.

// render loop
glm::vec3 lightColor;
lightColor.x = sin(glfwGetTime() * 2.0f);
lightColor.y = sin(glfwGetTime() * 0.7f);
lightColor.z = sin(glfwGetTime() * 1.3f);

glm::vec3 diffuseColor = lightColor   * glm::vec3(0.5f);
glm::vec3 ambientColor = diffuseColor * glm::vec3(0.2f);
  
lightingShader.setVec3("light.ambient", ambientColor);
lightingShader.setVec3("light.diffuse", diffuseColor);